Snakemake: remove output file

Question

I don't see how to use a Snakemake rule to remove a Snakemake output file that has become useless.

In concrete terms, I have a rule bwa_mem_sam that creates a file named {sample}.sam. I have this other rule, bwa_mem_bam that creates a file named {sample.bam}.

Has the two files contain the same information in different formats, I'd like to remove the first one cannot succeed doing this.

Any help would be very much appreciated. Ben.

rule bwa_mem_map:
    input:
        sam="{sample}.sam",
        bam="{sample}.bam"
    shell:
        "rm {input.sam}"

# Convert SAM to BAM.
rule bwa_mem_map_bam:
    input:
        rules.sam_to_bam.output


# Use bwa mem to map reads on a reference genome.
rule bwa_mem_map_sam:
    input:
        reference=reference_genome(),
        index=reference_genome_index(),
        fastq=lambda wildcards: config["units"][SAMPLE_TO_UNIT[wildcards.sample]],
    output:
        "mapping/{sample}.sam"
    threads: 12
    log: 
        "mapping/{sample}.log"
    shell:
        "{BWA} mem -t {threads} {input.reference} {input.fastq} > {output} 2> {log} "\
        "|| (rc=$?; cat {log}; exit $rc;)"


rule sam_to_bam:
    input:
        "{prefix}.sam"
    output:
        "{prefix}.bam"
    threads: 8
    shell:
        "{SAMTOOLS} view --threads {threads} -b {input} > {output}"

Answer 1

You don't need a rule to remove you sam files. Just mark the ouput sam file in "bwa_mem_map_sam" rule as temporary:

rule bwa_mem_map_sam:
    input:
        reference=reference_genome(),
        index=reference_genome_index(),
        fastq=lambda wildcards: config["units"][SAMPLE_TO_UNIT[wildcards.sample]],
    output:
        temp("mapping/{sample}.sam")
    threads: 12
    log: 
        "mapping/{sample}.log"
    shell:
        "{BWA} mem -t {threads} {input.reference} {input.fastq} > {output} 2> {log} "\
        "|| (rc=$?; cat {log}; exit $rc;)"

as soon as a temp file is not needed anymore (ie: not used as input in any other rule), it will be removed by snakemake.

EDIT AFTER COMMENT: If I understand correctly, your statement "if the user asks for a sam..." means the sam file is put in the target rule. If this is the case, then as long as the input of the target rule contains the sam file, the file won't be deleted (I guess). If the bam file is put in the target rule (and not the sam), then it will be deleted.

The other way is this:

rule bwa_mem_map:
    input:
        sam="{sample}.sam",
        bam="{sample}.bam"
    output:
        touch("{sample}_samErased.txt")
    shell:
        "rm {input.sam}"

and ask for "{sample}_samErased.txt" in the target rule.