How to abort a declarative pipeline

Question

I'm trying the new declarative pipeline syntax.

I wonder, how can I abort all the stages and steps of a pipeline, when for example a parameter has an invalid value.

I could add a when clause to every stage, but this isn't optimal for me. Is there a better way to do so?

Answer 1

This should work fine with a when directive, if you make use of the error step.

For example, you could do an up-front check and abort the build if the given parameter value is not acceptable — preventing subsequent stages from running:

pipeline {
  agent any
  parameters {
    string(name: 'targetEnv',
           defaultValue: 'dev',
           description: 'Must be "dev", "qa", or "staging"')
  }
  stages {
    stage('Validate parameters') {
      when {
        expression {
          // Only run this stage if the targetEnv is invalid
          !['dev', 'qa', 'staging'].contains(params.targetEnv)
        }
      }
      steps {
        // Abort the build, skipping subsequent stages
        error("Invalid target environment: ${params.targetEnv}")
      }
    }
    stage('Checkout') {
      steps {
        echo 'Checking out source code...'
      }
    }
    stage('Build') {
      steps {
        echo 'Building...'
      }
    }
  }
}