Deleting Sharepoint Files using XMLHTTP

Question

Following on from this excellent piece of work, here: Batch copy files to SharePoint site

I can now upload my zipped files to Sharepoint with a click of a button.

My problem is now thus: How do I delete the files I upload using the same method?

I've amended the code slightly to save different files to different SharePoint folders. Sample below:

 
Public Sub CopyToSharePoint()

Dim xmlhttp
Dim sharepointUrl
Dim sharepointFolder
Dim sharepointFileName
Dim LstrFileName, strFilePath, strMonthYear, PstrFullfileName, PstrTargetURL As String
Dim LlFileLength As Long
Dim Lvarbin() As Byte
Dim LvarBinData As Variant
Dim fso, LobjXML As Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim fldr As folder
Dim f As File

'Parent Sharepoint
sharepointUrl = "[SHAREPOINT PATH HERE]"

'Sets the Month%20Year
strMonthYear = Format(Now(), "mmmm yyyy") & "\"

'File Path
strFilePath = "[ARCHIVE DRIVE]" & strMonthYear

'Check to see if DRA for current month%20year exists
If Len(Dir(strFilePath, vbDirectory)) = 0 Then
    MkDir "strFilePath"
End If

Set LobjXML = CreateObject("Microsoft.XMLHTTP")

'Where we're uploading files from
Set fldr = fso.GetFolder(strFilePath)

For Each f In fldr.Files

If Format(f.DateCreated, "dd/mm/yyyy") = Format(Now(), "dd/mm/yyyy") Then

If InStr(1, f.Name, "[FILESTRING1]", vbTextCompare) > 0 Then
sharepointFolder = "[SHAREPOINTSTRING1]/"
    ElseIf InStr(1, f.Name, "[FILESTRING2]", vbTextCompare) > 0 Then
    sharepointFolder = "[SHAREPOINTSTRING2]"
        ElseIf InStr(1, f.Name, "[DONOTUPLOADTHISFILE]", vbTextCompare) > 0 Then
        GoTo NextF:
            Else
            sharepointFolder = "[SHAREPOINTMAINFOLDER]"
End If


sharepointFileName = sharepointUrl & sharepointFolder & f.Name

PstrFullfileName = strFilePath & f.Name
LlFileLength = FileLen(PstrFullfileName) - 1

' Read the file into a byte array.
ReDim Lvarbin(LlFileLength)
Open PstrFullfileName For Binary As #1
Get #1, , Lvarbin
Close #1

' Convert to variant to PUT.
LvarBinData = Lvarbin
PstrTargetURL = sharepointUrl & sharepointFolder & f.Name

' Put the data to the server, false means synchronous.
LobjXML.Open "PUT", PstrTargetURL, False


' Send the file in.
    LobjXML.Send LvarBinData

End If

NextF:
Next f

Set LobjXML = Nothing
  Set fso = Nothing

End Sub

Answer 1

I'd not closed the request to the server, d'oh! Setting it up in a separate instance solved it for me.

I didn't convert the filename to binary and then to variant, merely kept it as a string. You must omit the NOTHING from the last LobjXML.SEND given in LastCoder's example. Adding this in reproduces the Run-time error I give above.

Thanks for the help, LastCoder. Here's the amended code:

Public Sub DeleteFromSharePoint()

Dim xmlhttp
Dim sharepointUrl, sharepointFolder, sharepointFileName
Dim f, strZip As String
Dim LobjXML As Object

' Parent Sharepoint
sharepointUrl = "[SHAREPOINT URL]"

' In this test module, we're just deleting from the parent directory
sharepointFolder = ""

' Sets the report name we want to remove
f = "test"

' Sets the full .ZIP filename
' This is how reports are archived by date
strZip = f & "%20-%20" & Format(Now() - 1, "YYYY.MM.DD") & ".zip"

Set LobjXML = CreateObject("Microsoft.XMLHTTP")

    sharepointFileName = sharepointUrl & sharepointFolder & strZip

    ' Removes the data from the server, false means synchronous
    LobjXML.Open "DELETE", sharepointFileName, False

    ' Sends the request to remove the file
    LobjXML.Send

  Set LobjXML = Nothing

End Sub