Break down JSON string in simple perl or simple unix?

Question

ok so i have have this

{"status":0,"id":"7aceb216d02ecdca7ceffadcadea8950-1","hypotheses":[{"utterance":"hello how are you","confidence":0.96311796}]}

and at the moment i'm using this shell command to decode it to get the string i need,

echo $x | grep -Po '"utterance":.*?[^\\]"' | sed -e s/://g -e s/utterance//g -e 's/"//g'

but this only works when you have a grep compiled with perl and plus the script i use to get that JSON string is written in perl, so is there any way i can do this same decoding in a simple perl script or a simpler unix command, or better yet, c or objective-c?

the script i'm using to get the json is here, http://pastebin.com/jBGzJbMk and if you want a file to use then download http://trevorrudolph.com/a.flac

Answer 1

How about:

perl -MJSON -nE 'say decode_json($_)->{hypotheses}[0]{utterance}'

in script form:

use JSON;
while (<>) {
   print decode_json($_)->{hypotheses}[0]{utterance}, "\n"
}

Answer 2

Well, I'm not sure if I can deduce what you are after correctly, but this is a way to decode that JSON string in perl.

Of course, you'll need to know the data structure in order to get the data you need. The line that prints the "utterance" string is commented out in the code below.

use strict;
use warnings;
use Data::Dumper;
use JSON;

my $json = decode_json 
q#{"status":0,"id":"7aceb216d02ecdca7ceffadcadea8950-1","hypotheses":[{"utterance":"hello how are you","confidence":0.96311796}]}#;
#print $json->{'hypotheses'}[0]{'utterance'};
print Dumper $json;

Output:

$VAR1 = {
          'status' => 0,
          'hypotheses' => [
                            {
                              'utterance' => 'hello how are you',
                              'confidence' => '0.96311796'
                            }
                          ],
          'id' => '7aceb216d02ecdca7ceffadcadea8950-1'
        };

Quick hack:

while (<>) {
    say for /"utterance":"?(.*?)(?<!\\)"/;
}

Or as a one-liner:

perl -lnwe 'print for /"utterance":"(.+?)(?<!\\)"/g' inputfile.txt

The one-liner is troublesome if you happen to be using Windows, since " is interpreted by the shell.

Quick hack#2:

This will hopefully go through any hash structure and find keys.

my $json = decode_json $str;
say find_key($json, 'utterance');

sub find_key {
    my ($ref, $find) = @_;
    if (ref $ref) {
        if (ref $ref eq 'HASH' and defined $ref->{$find}) {
            return $ref->{$find};
        } else {
            for (values $ref) {
                my $found = find_key($_, $find);
                if (defined $found) {
                    return $found;
                }
            }
        }
    }
    return;
}